✨ [Artifact 1315] ドルフィンダイブを作成

Asset/data/asset/functions/artifact/1315.dolphin_dive/give/1.trigger.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1315.dolphin_dive/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1315} run function asset:artifact/1315.dolphin_dive/give/2.give

Asset/data/asset/functions/artifact/1315.dolphin_dive/give/2.give.mcfunction

@@ -0,0 +1,68 @@
+#> asset:artifact/1315.dolphin_dive/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1315.dolphin_dive/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1315
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:carrot_on_a_stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text":"ドルフィンダイブ","color":"#96FFFC"}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text":"前方に跳躍し、着地時に周囲にダメージを与える","color":"white"}','{"text":"使用後2秒間は落下ダメージを無効化する","color":"white"}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "mainhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onClick"
+# 神器の発動条件 (TextComponentString) (オプション)
+    data modify storage asset:artifact Condition set value '{"text":"地面に立っているか、水面にいる","color":"white"}'
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value [1000]
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Physical]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [Water]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "every"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackRange set value 6
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 100
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    # data modify storage asset:artifact LocalCooldown set value
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    data modify storage asset:artifact TypeCooldown.Type set value "shortRange"
+    data modify storage asset:artifact TypeCooldown.Duration set value 80
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Flora", "Urban", "Rumor"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give

Asset/data/asset/functions/artifact/1315.dolphin_dive/register.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1315.dolphin_dive/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[4] append value [1315]

Asset/data/asset/functions/artifact/1315.dolphin_dive/trigger/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1315.dolphin_dive/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1315} run function asset:artifact/1315.dolphin_dive/trigger/2.check_condition

Asset/data/asset/functions/artifact/1315.dolphin_dive/trigger/2.check_condition.mcfunction

@@ -0,0 +1,15 @@
+#> asset:artifact/1315.dolphin_dive/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1315.dolphin_dive/trigger/1.trigger
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/mainhand
+# 他にアイテム等確認する場合はここに書く
+
+# 地面に足をついている or 水面にいる(疑似的に判定)なら使用可能
+    execute if entity @s[tag=CanUsed] unless function asset:artifact/1315.dolphin_dive/trigger/predicate/on_ground unless function asset:artifact/1315.dolphin_dive/trigger/predicate/water_surface run tag @s remove CanUsed
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1315.dolphin_dive/trigger/3.main

Asset/data/asset/functions/artifact/1315.dolphin_dive/trigger/3.main.mcfunction

@@ -0,0 +1,35 @@
+#> asset:artifact/1315.dolphin_dive/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1315.dolphin_dive/trigger/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/mainhand
+
+# ここから先は神器側の効果の処理を書く
+
+# 演出
+    execute positioned ~ ~0.3 ~ rotated ~ 0 run function asset:artifact/1315.dolphin_dive/trigger/vfx
+    playsound entity.dolphin.jump player @a ~ ~ ~ 0.8 1.1
+    playsound entity.dolphin.jump player @a ~ ~ ~ 0.8 1.0
+    playsound entity.dolphin.jump player @a ~ ~ ~ 0.8 0.9
+    playsound minecraft:entity.dolphin.splash player @a ~ ~ ~ 1 1
+    execute if predicate lib:random_pass_per/50 run playsound minecraft:entity.dolphin.play player @a ~ ~ ~ 0.7 1
+
+# Motion
+    data modify storage lib: Argument.VectorMagnitude set value 1.1d
+    execute rotated ~ -65 run function lib:motion/looking
+
+# 攻撃用エフェクト付与
+    data modify storage api: Argument.ID set value 341
+    data modify storage api: Argument.FieldOverride.Damage set value 1000
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# 落下ダメージ無効
+    data modify storage api: Argument.ID set value 190
+    data modify storage api: Argument.Stack set value 10
+    data modify storage api: Argument.Duration set value 40
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset

Asset/data/asset/functions/artifact/1315.dolphin_dive/trigger/predicate/on_ground.mcfunction

@@ -0,0 +1,9 @@
+#> asset:artifact/1315.dolphin_dive/trigger/predicate/on_ground
+#
+#
+#
+# @within function asset:artifact/1315.dolphin_dive/trigger/2.check_condition
+
+# OnGround:1bなら成功
+    function api:data_get/on_ground
+    execute if data storage api: {OnGround:true} run return 1

Asset/data/asset/functions/artifact/1315.dolphin_dive/trigger/predicate/water_surface.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1315.dolphin_dive/trigger/predicate/water_surface
+#
+#
+#
+# @within function asset:artifact/1315.dolphin_dive/trigger/2.check_condition
+
+# 足元が水 かつ 顔が水中でないなら成功
+    execute if block ~ ~ ~ water anchored eyes unless block ^ ^ ^ water run return 1

Asset/data/asset/functions/artifact/1315.dolphin_dive/trigger/vfx.mcfunction

@@ -0,0 +1,68 @@
+#> asset:artifact/1315.dolphin_dive/trigger/vfx
+#
+#
+#
+# @within function asset:artifact/1315.dolphin_dive/trigger/3.main
+
+# [ImportKey]: NobwRALgngDgpmAXGAxgSwE4oDYIDRgCuhaAJkmAJwAslcARqQBwCGAtAEwBs9AZm9QCMABmpt6LJhzaUucOCiaVhKAMwBWFGAIA7FgFsEyQGGKAAkHawMFhgMBnJOBQB7QjohIuwgijju4GI5gAG4s2IRG4AAeSN5gULEAvokEtqRohA6I6sK5ebkEdhA2HohxcNjYaDB2RiJxGM7FEEZxaHYAopXVtR0AjoRh2FAAyta+5Ii8YbXJALpAA_3
+# 円 1
+particle cloud ~ ~ ~ ^0 ^ ^-500000000 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^52264231.63383 ^ ^-497260947.68414 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^103955845.40888 ^ ^-489073800.3669 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^154508497.18747 ^ ^-475528258.14758 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^203368321.5379 ^ ^-456772728.8213 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^250000000 ^ ^-433012701.89222 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^293892626.14624 ^ ^-404508497.18747 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^334565303.17943 ^ ^-371572412.7387 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^371572412.7387 ^ ^-334565303.17943 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^404508497.18747 ^ ^-293892626.14624 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^433012701.89222 ^ ^-250000000 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^456772728.8213 ^ ^-203368321.5379 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^475528258.14758 ^ ^-154508497.18747 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^489073800.3669 ^ ^-103955845.40888 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^497260947.68414 ^ ^-52264231.63383 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^500000000 ^ ^0 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^497260947.68414 ^ ^52264231.63383 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^489073800.3669 ^ ^103955845.40888 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^475528258.14758 ^ ^154508497.18747 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^456772728.8213 ^ ^203368321.5379 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^433012701.89222 ^ ^250000000 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^404508497.18747 ^ ^293892626.14624 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^371572412.7387 ^ ^334565303.17943 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^334565303.17943 ^ ^371572412.7387 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^293892626.14624 ^ ^404508497.18747 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^250000000 ^ ^433012701.89222 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^203368321.5379 ^ ^456772728.8213 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^154508497.18747 ^ ^475528258.14758 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^103955845.40888 ^ ^489073800.3669 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^52264231.63383 ^ ^497260947.68414 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^0 ^ ^500000000 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-52264231.63383 ^ ^497260947.68414 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-103955845.40888 ^ ^489073800.3669 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-154508497.18747 ^ ^475528258.14758 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-203368321.5379 ^ ^456772728.8213 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-250000000 ^ ^433012701.89222 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-293892626.14624 ^ ^404508497.18747 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-334565303.17943 ^ ^371572412.7387 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-371572412.7387 ^ ^334565303.17943 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-404508497.18747 ^ ^293892626.14624 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-433012701.89222 ^ ^250000000 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-456772728.8213 ^ ^203368321.5379 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-475528258.14758 ^ ^154508497.18747 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-489073800.3669 ^ ^103955845.40888 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-497260947.68414 ^ ^52264231.63383 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-500000000 ^ ^0 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-497260947.68414 ^ ^-52264231.63383 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-489073800.3669 ^ ^-103955845.40888 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-475528258.14758 ^ ^-154508497.18747 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-456772728.8213 ^ ^-203368321.5379 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-433012701.89222 ^ ^-250000000 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-404508497.18747 ^ ^-293892626.14624 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-371572412.7387 ^ ^-334565303.17943 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-334565303.17943 ^ ^-371572412.7387 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-293892626.14624 ^ ^-404508497.18747 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-250000000 ^ ^-433012701.89222 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-203368321.5379 ^ ^-456772728.8213 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-154508497.18747 ^ ^-475528258.14758 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-103955845.40888 ^ ^-489073800.3669 0.000000001 0 normal @a
+particle cloud ~ ~ ~ ^-52264231.63383 ^ ^-497260947.68414 0.000000001 0 normal @a

Asset/data/asset/functions/effect/0341.dolphin_dive/_/register.mcfunction

@@ -0,0 +1,7 @@
+#> asset:effect/0341.dolphin_dive/_/register
+#
+#
+#
+# @within tag/function asset:effect/register
+
+execute if data storage asset:context {id:341} run function asset:effect/0341.dolphin_dive/register

Asset/data/asset/functions/effect/0341.dolphin_dive/_/tick.mcfunction

@@ -0,0 +1,7 @@
+#> asset:effect/0341.dolphin_dive/_/tick
+#
+# Effectが発動している間毎tick実行されるfunction
+#
+# @within tag/function asset:effect/tick
+
+execute if data storage asset:context {id:341} run function asset:effect/0341.dolphin_dive/tick/

Asset/data/asset/functions/effect/0341.dolphin_dive/register.mcfunction

@@ -0,0 +1,39 @@
+#> asset:effect/0341.dolphin_dive/register
+#
+# Effectのデータを指定
+#
+# @within function asset:effect/0341.dolphin_dive/_/register
+
+# ExtendsSafe (boolean) (default = false)
+    # data modify storage asset:effect ExtendsSafe set value true
+# ID (int)
+    data modify storage asset:effect ID set value 341
+# 名前 (TextComponentString)
+    data modify storage asset:effect Name set value '{"text":"ドルフィンダイブ"}'
+# 説明文 (TextComponentString[])
+    data modify storage asset:effect Description set value []
+# 効果時間 (int) (default = API || error)
+    data modify storage asset:effect Duration set value 100
+# スタック (int) (default = API || 1)
+    # data modify storage asset:effect Stack set value
+# 効果時間の操作方法 (default = API || "replace")
+    # data modify storage asset:effect DurationOperation set value
+# スタックの操作方法 (default = API || "replace")
+    # data modify storage asset:effect StackOperation set value
+# 最大効果時間 (int) (default = 2147483647)
+    # data modify storage asset:effect MaxDuration set value
+# 最大スタック (int) (default = 2147483647)
+    data modify storage asset:effect MaxStack set value 1
+# 悪い効果か否か (boolean)
+    data modify storage asset:effect IsBadEffect set value false
+# 死亡時のエフェクトの処理 (default = "remove")
+    # data modify storage asset:effect ProcessOnDied set value
+# 消すのに必要なレベル (int) (default = 1)
+    data modify storage asset:effect RequireClearLv set value 4
+# エフェクトをUIに表示するか (boolean) (default = true)
+    data modify storage asset:effect Visible set value false
+# エフェクトのスタックををUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect StackVisible set value
+
+# フィールド
+    data modify storage asset:effect Field.Delay set value 6

Asset/data/asset/functions/effect/0341.dolphin_dive/tick/.mcfunction

@@ -0,0 +1,22 @@
+#> asset:effect/0341.dolphin_dive/tick/
+#
+# Effectのtick処理
+#
+# @within function asset:effect/0341.dolphin_dive/_/tick
+
+# 演出
+    particle dolphin ~ ~1 ~ 0.4 0.3 0.4 0 5 normal @a
+    particle dust 0.4 1 1 1 ~ ~1 ~ 0.3 0.4 0.3 0 2 normal @a
+
+# 最初の数tickは着地検知を無効とする
+    execute store result storage asset:context this.Delay int 0.9999999999 run data get storage asset:context this.Delay
+    execute unless data storage asset:context this{Delay:0} run return fail
+
+# 着地検知
+    function api:data_get/on_ground
+
+# 着地
+    execute if data storage api: {OnGround:1b} run function asset:effect/0341.dolphin_dive/tick/landing
+
+# OnGround:0bかつすぐ下が水なら水面とみなして発動
+    execute if data storage api: {OnGround:0b} if block ~ ~-0.5 ~ water align y run function asset:effect/0341.dolphin_dive/tick/landing

Asset/data/asset/functions/effect/0341.dolphin_dive/tick/landing.mcfunction

@@ -0,0 +1,20 @@
+#> asset:effect/0341.dolphin_dive/tick/landing
+#
+#
+#
+# @within function asset:effect/0341.dolphin_dive/tick/
+
+# Durationを0にしてエフェクト解除
+    data modify storage asset:context Duration set value 0
+
+    tp @s @s
+
+# PlayerMotion
+    data modify storage lib: Argument.VectorMagnitude set value 0.7d
+    execute rotated ~ -65 run function lib:motion/looking
+
+# Object召喚
+    data modify storage api: Argument.ID set value 1151
+    data modify storage api: Argument.FieldOverride.Damage set from storage asset:context this.Damage
+    execute store result storage api: Argument.FieldOverride.UserID int 1 run scoreboard players get @s UserID
+    function api:object/summon

Asset/data/asset/functions/object/1151.dolphin_dive/register.mcfunction

@@ -0,0 +1,21 @@
+#> asset:object/1151.dolphin_dive/register
+#
+# Objectのデータを指定
+#
+# @within function asset:object/alias/1151/register
+
+# 継承(オプション)
+    data modify storage asset:object Extends append value 2
+    function asset:object/extends
+# 他のObjectに継承されることを許可するか (boolean) (オプション)
+    # data modify storage asset:object ExtendsSafe set value
+# 継承されることを前提とした、抽象的なObjectであるかどうか(boolean)
+    data modify storage asset:object IsAbstract set value false
+# Tickするかどうか(boolean) (オプション)
+    # data modify storage asset:object IsTicking set value
+
+# ID (int)
+    data modify storage asset:object ID set value 1151
+# フィールド(オプション)
+    data modify storage asset:object Field.Damage set value 1
+    data modify storage asset:object Field.UserID set value -1

Asset/data/asset/functions/object/1151.dolphin_dive/summon/.mcfunction

@@ -0,0 +1,8 @@
+#> asset:object/1151.dolphin_dive/summon/
+#
+# Object召喚処理の呼び出し時に実行されるfunction
+#
+# @within asset:object/alias/1151/summon
+
+# 元となるEntityを召喚する
+    summon marker ~ ~ ~ {Tags:["ObjectInit"]}

Asset/data/asset/functions/object/1151.dolphin_dive/tick/.mcfunction

@@ -0,0 +1,16 @@
+#> asset:object/1151.dolphin_dive/tick/
+#
+# Objectのtick時の処理
+#
+# @within asset:object/alias/1151/tick
+
+# Tick加算
+    scoreboard players add @s General.Object.Tick 1
+
+# 波
+    execute if score @s General.Object.Tick matches 1 run function asset:object/1151.dolphin_dive/tick/wave/1
+    execute if score @s General.Object.Tick matches 4 run function asset:object/1151.dolphin_dive/tick/wave/2
+    execute if score @s General.Object.Tick matches 9 run function asset:object/1151.dolphin_dive/tick/wave/3
+
+# 消滅処理
+    kill @s[scores={General.Object.Tick=9..}]