libargparse/CMakeLists.txt at master · yazimut/libargparse · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
cmake_minimum_required(VERSION 3.13)
set(PROJECT libargparse)
project(${PROJECT} CXX)
set(GLOBAL_LIB_NAME argparse)
message(STATUS "Configuring ${PROJECT}")


set(CMAKE_CXX_FLAGS_DEBUG "")
set(CMAKE_CXX_FLAGS_RELEASE "")

set(LIBARGPARSE_PROJECT_ROOT ${CMAKE_CURRENT_SOURCE_DIR})

if(WIN32)
    set(REDIRECT_TO_NULL > NUL)
else()
    set(REDIRECT_TO_NULL > /dev/null)
endif()


### Lib type
if(NOT DEFINED ARGPARSE_LIB_TYPE)
    set(ARGPARSE_LIB_TYPE SHARED)
    message(STATUS "ARGPARSE_LIB_TYPE wasn't set, using default: ${ARGPARSE_LIB_TYPE}")
endif()

if(ARGPARSE_LIB_TYPE MATCHES "STATIC|SHARED")
    message(STATUS "${GLOBAL_LIB_NAME} type: ${ARGPARSE_LIB_TYPE}")
else()
    message(FATAL_ERROR "invalid ARGPARSE_LIB_TYPE: ${ARGPARSE_LIB_TYPE}. Available: STATIC or SHARED")
endif()


### Extract lib version
# Read version file
set(VERSION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/include/${GLOBAL_LIB_NAME}/version.hpp")
if(NOT EXISTS ${VERSION_FILE})
    message(FATAL_ERROR "${GLOBAL_LIB_NAME} (or include/${GLOBAL_LIB_NAME}/version.hpp) hasn't been found!")
endif()
file(READ ${VERSION_FILE} VERSION_FILE_CONTENT)

# Extract version
string(REGEX MATCH "ARGPARSE_VERSION_MAJOR = ([0-9]+)" _ ${VERSION_FILE_CONTENT})
set(ARGPARSE_VERSION_MAJOR ${CMAKE_MATCH_1})

string(REGEX MATCH "ARGPARSE_VERSION_MINOR = ([0-9]+)" _ ${VERSION_FILE_CONTENT})
set(ARGPARSE_VERSION_MINOR ${CMAKE_MATCH_1})

string(REGEX MATCH "ARGPARSE_VERSION_PATCH = ([0-9]+)" _ ${VERSION_FILE_CONTENT})
set(ARGPARSE_VERSION_PATCH ${CMAKE_MATCH_1})

# Concatenation
set(ARGPARSE_VERSION "${ARGPARSE_VERSION_MAJOR}.${ARGPARSE_VERSION_MINOR}.${ARGPARSE_VERSION_PATCH}")
message(STATUS "${GLOBAL_LIB_NAME} version: ${ARGPARSE_VERSION}")


### Target
set(SOURCES_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src)
set(PUBLIC_INCLUDES ${CMAKE_CURRENT_SOURCE_DIR}/include)
set(PRIVATE_INCLUDES ${SOURCES_DIR})
file(GLOB_RECURSE PUBLIC_HEADERS "${PUBLIC_INCLUDES}/*.hpp")
file(GLOB_RECURSE PRIVATE_HEADERS "${PRIVATE_INCLUDES}/*.hpp")
file(GLOB_RECURSE SOURCES "${SOURCES_DIR}/*.cpp")

set(TARGET ${GLOBAL_LIB_NAME})
add_library(${TARGET}
    ${ARGPARSE_LIB_TYPE}
    ${SOURCES}
    ${PUBLIC_HEADERS} ${PRIVATE_HEADERS}
)
target_include_directories(${TARGET}
    PUBLIC
        ${PUBLIC_INCLUDES}
    PRIVATE
        ${PRIVATE_INCLUDES}
)
target_compile_definitions(${TARGET}
    PUBLIC
        $<$<STREQUAL:${ARGPARSE_LIB_TYPE},STATIC>:ARGPARSE_STATIC>
        $<$<STREQUAL:${ARGPARSE_LIB_TYPE},SHARED>:ARGPARSE_SHARED>
    PRIVATE
        $<$<CONFIG:Debug>:DEBUG> $<$<CONFIG:Release>:NDEBUG>
        $<$<STREQUAL:${ARGPARSE_LIB_TYPE},SHARED>:ARGPARSE_EXPORTS>
)
target_compile_options(${TARGET}
    PUBLIC
    PRIVATE
        $<$<CONFIG:Debug>:-g3 -Og> $<$<CONFIG:Release>:-g0 -O3>
        -Wall -Wextra -Wpedantic $<$<CONFIG:Release>:-Werror -Wno-error=deprecated>
        -std=c++11 -pipe
        $<$<STREQUAL:${ARGPARSE_LIB_TYPE},SHARED>:-fvisibility=hidden>
)
target_link_options(${TARGET} PUBLIC PRIVATE)
target_link_directories(${TARGET} PUBLIC PRIVATE)
target_link_libraries(${TARGET} PUBLIC PRIVATE)
set_target_properties(${TARGET}
    PROPERTIES
        PUBLIC_HEADER "${PUBLIC_HEADERS}"
        DEFINE_SYMBOL ""
        VERSION       "${ARGPARSE_VERSION}"
        SOVERSION     "${ARGPARSE_VERSION_MAJOR}"
)


### Documentation
find_package(Doxygen REQUIRED)
if(NOT DOXYGEN_FOUND)
    message(FATAL_ERROR "Doxygen not found in system")
endif()

# Generate docs target
set(DOXYFILE "doc/Doxyfile")
if(CMAKE_BUILD_TYPE STREQUAL "Release")
    set(DOCS_BUILD ALL)
endif()

add_custom_target(docs ${DOCS_BUILD}
    COMMAND ${CMAKE_COMMAND} -E env ${DOXYGEN_EXECUTABLE} ${DOXYFILE} ${REDIRECT_TO_NULL}
    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
    COMMENT "Generating API documentation with Doxygen"
    VERBATIM
)

# Remove docs target
add_custom_target(docs-clean
    COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_CURRENT_SOURCE_DIR}/doc/html
    COMMENT "Removing docs"
)


### Test app
add_subdirectory("${CMAKE_CURRENT_SOURCE_DIR}/tests/test_app")