libspatialaudio/meson.build at master · videolan/libspatialaudio · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
project(
    'libspatialaudio',
    'cpp',
    version : '0.4.0',
    meson_version : '>= 1.1.0',
    default_options : ['warning_level=3', 'cpp_std=c++14'],
)

cpp = meson.get_compiler('cpp')
dependencies = []
conf_data = configuration_data()

libmysofa_dep = dependency('libmysofa', required : get_option('libmysofa'))
if libmysofa_dep.found()
    conf_data.set('SPATIALAUDIO_SUPPORTS_SOFA', 1)
    dependencies += libmysofa_dep
endif

if get_option('mit_hrtf').allowed()
    conf_data.set('SPATIALAUDIO_SUPPORTS_MIT_HRTF', 1)
    add_languages('c', native: false)
endif

if get_option('default_library') == 'static'
    conf_data.set('SPATIALAUDIO_STATIC', 1)
endif

subdir('include')
subdir('source')

# Make the library usable as a Meson subproject.
libspatialaudio_dep = declare_dependency(
    include_directories : spatialaudio_incdirs,
    dependencies : dependencies,
    link_with : spatialaudio_lib,
)
meson.override_dependency('libspatialaudio', libspatialaudio_dep)

# Make this library properly installable
install_headers(spatialaudio_headers,
    subdir : 'spatialaudio',
    preserve_path : true,
)

pkg_mod = import('pkgconfig')
pkg_mod.generate(
    spatialaudio_lib,
    description : 'Spatial audio rendering library',
)

subdir('tests')