Initial commit

Author: nseidle

.gitattributes

@@ -0,0 +1,2 @@
+# Auto detect text files and perform LF normalization
+* text=auto

LICENSE.md

@@ -0,0 +1,55 @@
+SparkFun License Information
+============================
+
+SparkFun uses two different licenses for our files — one for hardware and one for code.
+
+Hardware
+---------
+
+**SparkFun hardware is released under [Creative Commons Share-alike 4.0 International](http://creativecommons.org/licenses/by-sa/4.0/).**
+
+Note: This is a human-readable summary of (and not a substitute for) the [license](http://creativecommons.org/licenses/by-sa/4.0/legalcode).
+
+You are free to:
+
+Share — copy and redistribute the material in any medium or format
+Adapt — remix, transform, and build upon the material
+for any purpose, even commercially.
+The licensor cannot revoke these freedoms as long as you follow the license terms.
+Under the following terms:
+
+Attribution — You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
+ShareAlike — If you remix, transform, or build upon the material, you must distribute your contributions under the same license as the original.
+No additional restrictions — You may not apply legal terms or technological measures that legally restrict others from doing anything the license permits.
+Notices:
+
+You do not have to comply with the license for elements of the material in the public domain or where your use is permitted by an applicable exception or limitation.
+No warranties are given. The license may not give you all of the permissions necessary for your intended use. For example, other rights such as publicity, privacy, or moral rights may limit how you use the material.
+
+
+Code
+--------
+
+**SparkFun code, firmware, and software is released under the MIT License(http://opensource.org/licenses/MIT).**
+
+The MIT License (MIT)
+
+Copyright (c) 2016 SparkFun Electronics
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

README.md

@@ -0,0 +1,38 @@
+SparkFun Qwiic I2C Mux Arduino Library
+===========================================================
+
+ [![SparkFun Qwiic Mux - TCA9548 (BOB-14685)](https://cdn.sparkfun.com//assets/parts/1/2/8/9/0/14685-SparkFun_Qwiic_Mux_Breakout_-_8_Channel__TCA9548A_-01.jpg)](https://www.sparkfun.com/products/15242) 
+
+[*SparkFun Qwiic Mux - TCA9548 (BOB-14685)*](https://www.sparkfun.com/products/14685)
+
+Do you have too many sensors with the same I<sup>2</sup>C address? Put them on the SparkFun Qwiic Mux Breakout to get them all talking on the same bus! The Qwiic Mux Breakout enables communication with multiple I<sup>2</sup>C devices that have the same address that makes it simple to interface with. The Qwiic Mux also has eight configurable addresses of its own, allowing for up to 64 I<sup>2</sup>C buses on a connection. To make it even easier to use this multiplexer, all communication is enacted exclusively via I<sup>2</sup>C, utilizing our handy Qwiic system.
+
+The Qwiic Mux also allows you to change the last three bits of the address byte, allowing for eight jumper selectable addresses if you happen to need to put more than one Qwiic Mux Breakout on the same I<sup>2</sup>C port. The address can be changed by adding solder to any of the three ADR jumpers. Each SparkFun Qwiic Mux Breakout operate between 1.65V and 5.5V making it ideal for all of the Qwiic boards we produce in house.
+
+SparkFun labored with love to create this code. Feel like supporting open source hardware? 
+Buy a [board](https://www.sparkfun.com/products/14685) from SparkFun!
+
+Repository Contents
+-------------------
+
+* **/examples** - Example sketches for the library (.ino). Run these from the Arduino IDE. 
+* **/src** - Source files for the library (.cpp, .h).
+* **keywords.txt** - Keywords from this library that will be highlighted in the Arduino IDE. 
+* **library.properties** - General library properties for the Arduino package manager. 
+
+Documentation
+--------------
+
+* **[Installing an Arduino Library Guide](https://learn.sparkfun.com/tutorials/installing-an-arduino-library)** - Basic information on how to install an Arduino library.
+* **[Product Repository](https://github.com/sparkfun/Qwiic_Mux_TCA9548A)** - Main repository (including hardware files)
+
+License Information
+-------------------
+
+This product is _**open source**_! 
+
+Please use, reuse, and modify these files as you see fit. Please maintain attribution to SparkFun Electronics and release anything derivative under the same license.
+
+Distributed as-is; no warranty is given.
+
+- Your friends at SparkFun.

examples/Example1_BasicControl/Example1_BasicControl.ino

@@ -0,0 +1,102 @@
+/*
+  Use the Qwiic Mux to access multiple I2C devices on seperate busses.
+  By: Nathan Seidle @ SparkFun Electronics
+  Date: May 17th, 2020
+  License: This code is public domain but you buy me a beer if you use this 
+  and we meet someday (Beerware license).
+
+  Some I2C devices respond to only one I2C address. This can be a problem
+  when you want to hook multiple of a device to the I2C bus. An I2C Mux 
+  solves this issue by allowing you to change the 'channel' or port that
+  a device is connected to on the mux.
+
+  This example shows how to hook up two MMA8452Q accelerometers with the same address.
+  You can read the MMA8452Q hookup guide and get the library from https://learn.sparkfun.com/tutorials/mma8452q-accelerometer-breakout-hookup-guide
+
+  The TCA9548A is a mux. This means when you enableMuxPort(2) then the SDA and SCL lines of the master (Arduino)
+  are connected to port 2. Whatever I2C traffic you do, such as accel.init() will be communicated to whatever
+  sensor you have on port 2. You don't need accel2.init() or accel5.init().
+
+  Outputs two sets of XYZ acceleration
+
+  Hardware Connections:
+  Attach the Qwiic Mux Shield to your RedBoard or Uno.
+  Plug two Qwiic MMA8452Q breakout boards into ports 0 and 1.
+  Serial.print it out at 9600 baud to serial monitor.
+
+  SparkFun labored with love to create this code. Feel like supporting open
+  source? Buy a board from SparkFun!
+  https://www.sparkfun.com/products/14685
+
+*/
+
+#include <Wire.h>
+
+TwoWire Wire1(1); //Will use pads 8/9
+
+#include <SparkFun_I2C_Mux_Arduino_Library.h> //Click here to get the library: http://librarymanager/All#SparkFun_I2C_Mux
+QWIICMUX myMux;
+
+#include <SparkFun_MMA8452Q.h> //Click here to get the library: http://librarymanager/All#SparkFun_MMA8452
+MMA8452Q accel;
+
+#define NUMBER_OF_SENSORS 2
+
+void setup()
+{
+  Serial.begin(115200);
+  Serial.println("Qwiic Mux Shield Read Example");
+
+  Wire1.begin();
+  if (myMux.begin(0x70, Wire1) == false)
+  {
+    Serial.println("Mux not detected. Freezing...");
+    while (1)
+      ;
+  }
+  Serial.println("Mux detected");
+
+  //myMux.setPort(8);
+  byte currentPortNumber = myMux.getPort();
+  Serial.print("CurrentPort: ");
+  Serial.println(currentPortNumber);
+
+  while (1)
+    ;
+
+  //Initialize all the sensors
+  for (byte x = 0; x < NUMBER_OF_SENSORS; x++)
+  {
+    myMux.setPort(x); //Tell mux to connect to port X
+    accel.init();     //Init the sensor connected to this port
+  }
+
+  Serial.println("Mux Shield online");
+}
+
+void loop()
+{
+  for (byte x = 0; x < NUMBER_OF_SENSORS; x++)
+  {
+    myMux.setPort(x); //Tell mux to connect to this port, and this port only
+
+    if (accel.available())
+    {
+      accel.read();
+
+      Serial.print("Accel ");
+      Serial.print(x);
+      Serial.print(": ");
+      Serial.print(accel.cx, 2);
+      Serial.print(" ");
+      Serial.print(accel.cy, 2);
+      Serial.print(" ");
+      Serial.print(accel.cz, 2);
+      Serial.print(" ");
+
+      Serial.println(); // Print new line every time.
+    }
+  }
+
+  delay(1); //Wait for next reading
+}

keywords.txt

@@ -0,0 +1,27 @@
+#######################################
+# Syntax Coloring Map
+#######################################
+
+#######################################
+# Datatypes (KEYWORD1)
+#######################################
+
+QWIICMUX	KEYWORD1
+
+#######################################
+# Methods and Functions (KEYWORD2)
+#######################################
+
+begin	KEYWORD2
+isConnected	KEYWORD2
+setPort	KEYWORD2
+setPortState	KEYWORD2
+getPort	KEYWORD2
+getPortState	KEYWORD2
+enablePort	KEYWORD2
+disablePort	KEYWORD2
+
+#######################################
+# Constants (LITERAL1)
+#######################################
+

library.properties

@@ -0,0 +1,9 @@
+name=SparkFun I2C Mux Arduino Library
+version=1.0.0
+author=SparkFun Electronics
+maintainer=SparkFun Electronics
+sentence=Library to control I2C multiplexers including the TCA9548/PCA9548.
+paragraph=I2C multiplexers are useful for connecting multiple I2C devices that have only one address. This library makes it easy to work with the 8-channel TCA9548/PCA9548 I2C multiplexer but also works with smaller 4 and 2 bit multiplexers. This library support daisychaining multiple muxes so that you can get up to 64 devices on one I2C bus! It also supports generic Wire ports (Wire1, myWire, etc). Checkout the <a href="https://www.sparkfun.com/products/14685">Qwiic Mux</a> for more information.
+category=Device Control
+url=https://github.com/sparkfun/SparkFun_I2C_Mux_Arduino_Library
+architectures=*

src/SparkFun_I2C_Mux_Arduino_Library.cpp

@@ -0,0 +1,141 @@
+/*
+  This is an Arduino library written for the TCA9548A/PCA9548A 8-bit multiplexer.
+  By Nathan Seidle @ SparkFun Electronics, May 16th, 2020
+
+  The TCA9548A/PCA9548A allows for up to 8 devices to be attached to a single
+  I2C bus. This is helpful for I2C devices that have a single I2C address.
+
+  https://github.com/sparkfun/SparkFun_I2C_Mux_Arduino_Library
+
+  SparkFun labored with love to create this code. Feel like supporting open
+  source? Buy a board from SparkFun!
+  https://www.sparkfun.com/products/14685
+*/
+
+#include "SparkFun_I2C_Mux_Arduino_Library.h"
+
+//Sets up the Mux for basic function
+//Returns true if device responded correctly. All ports will be disabled.
+bool QWIICMUX::begin(uint8_t deviceAddress, TwoWire &wirePort)
+{
+  //Get user's options
+  _i2cPort = &wirePort;
+  _deviceAddress = deviceAddress;
+
+  //Valid addresses for the TCA9548 are 0x70 to 0x77.
+  //We don't check the validity of the address. There may be other I2C mux's outside of this range.
+
+  //Check if the device ack's over I2C
+  if (isConnected() == false)
+    return (false);
+  return (true);
+}
+
+//Returns true if device is present
+//Tests for device ack to I2C address
+//Then tests if device behaves as we expect
+//Leaves with all ports disabled
+bool QWIICMUX::isConnected()
+{
+  _i2cPort->beginTransmission(_deviceAddress);
+  if (_i2cPort->endTransmission() != 0)
+    return (false); //Device did not ACK
+
+  //Write to device, expect a return
+  setPortState(0xA4); //Set port register to a known value
+  uint8_t response = getPortState();
+  setPortState(0x00);   //Disable all ports
+  if (response == 0xA4) //Make sure we got back what we expected
+    return (true);      //All good
+  return (false);
+}
+
+//Enables one port. Disables all others.
+//If port number if out of range, disable all ports
+bool QWIICMUX::setPort(uint8_t portNumber)
+{
+  uint8_t portValue = 0;
+
+  if (portNumber > 7)
+    portValue = 0; //If port number is out of range, turn off all ports
+  else
+    portValue = 1 << portNumber;
+
+  _i2cPort->beginTransmission(_deviceAddress);
+  _i2cPort->write(portValue);
+  if (_i2cPort->endTransmission() != 0)
+    return (false); //Device did not ACK
+  return (true);
+}
+
+//Returns the first port number bit that is set
+//Returns 255 if no port is enabled
+uint8_t QWIICMUX::getPort()
+{
+  //Read the current mux settings
+  _i2cPort->beginTransmission(_deviceAddress);
+  _i2cPort->requestFrom(_deviceAddress, 1);
+  if (!_i2cPort->available())
+    return (255); //Error
+  uint8_t portBits = _i2cPort->read();
+
+  //Search for the first set bit, then return its location
+  for (uint8_t x = 0; x < 8; x++)
+  {
+    if (portBits & (1 << x))
+      return (x);
+  }
+  return (255); //Return no port set
+}
+
+//Writes a 8-bit value to mux
+//Overwrites any other bits
+//This allows us to enable/disable multiple ports at same time
+bool QWIICMUX::setPortState(uint8_t portBits)
+{
+  _i2cPort->beginTransmission(_deviceAddress);
+  _i2cPort->write(portBits);
+  if (_i2cPort->endTransmission() != 0)
+    return (false); //Device did not ACK
+  return (true);
+}
+
+//Gets the current port state
+//Returns byte that may have multiple bits set
+uint8_t QWIICMUX::getPortState()
+{
+  //Read the current mux settings
+  _i2cPort->beginTransmission(_deviceAddress);
+  _i2cPort->requestFrom(_deviceAddress, 1);
+  return (_i2cPort->read());
+}
+
+//Enables a specific port number
+//This allows for multiple ports to be 'turned on' at the same time. Use with caution.
+bool QWIICMUX::enablePort(uint8_t portNumber)
+{
+  if (portNumber > 7)
+    portNumber = 7; //Error check
+
+  //Read the current mux settings
+  uint8_t settings = getPortState();
+
+  //Set the wanted bit to enable the port
+  settings |= (1 << portNumber);
+
+  return (setPortState(settings));
+}
+
+//Disables a specific port number
+bool QWIICMUX::disablePort(uint8_t portNumber)
+{
+  if (portNumber > 7)
+    portNumber = 7; //Error check
+
+  uint8_t settings = getPortState();
+
+  //Clear the wanted bit to disable the port
+  settings &= ~(1 << portNumber);
+
+  return (setPortState(settings));
+}