opentcs-integration-example/build.gradle at master · openTCS/opentcs-integration-example · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
buildscript {
  repositories {
    mavenLocal()
    mavenCentral()
    maven {
      url "https://plugins.gradle.org/m2/"
    }
  }
}

plugins {
  alias(libs.plugins.jacocolog)
}

apply plugin: 'base'
apply plugin: 'distribution'
apply plugin: 'groovy'

apply from: "${rootDir}/gradle/common.gradle"
apply from: "${rootDir}/gradle/publishing-common.gradle"

repositories {
  mavenLocal()
  mavenCentral()
}

dependencies {
  implementation localGroovy()
  implementation libs.commons.io
}

subprojects {
  apply from: rootProject.file('gradle/common.gradle')
}

distributions {
  main {
    contents.from {
      project(':opentcs-example-kernel').ext.collectableDistDir
    }
    contents.from {
      project(':opentcs-example-kernelcontrolcenter').ext.collectableDistDir
    }
    contents.from {
      project(':opentcs-example-modeleditor').ext.collectableDistDir
    }
    contents.from {
      project(':opentcs-example-operationsdesk').ext.collectableDistDir
    }
    contents.from {
      project(':opentcs-example-documentation').ext.collectableDistDir
    }
  }
}

task subDists {
  dependsOn(':opentcs-example-kernel:installDist')
  dependsOn(':opentcs-example-kernelcontrolcenter:installDist')
  dependsOn(':opentcs-example-modeleditor:installDist')
  dependsOn(':opentcs-example-operationsdesk:installDist')
  dependsOn(':opentcs-example-documentation:installDist')
}

installDist.dependsOn subDists

distZip {
  archiveClassifier = 'bin'
  dependsOn subDists
}

distTar {
  enabled = false
  archiveClassifier = 'bin'
  dependsOn subDists
}

task distSrcZip(type: Zip) {
  archiveClassifier = 'src'
  from "${rootDir}"

  includes << 'config/**'
  includes << 'gradle/**'
  includes << 'lib/**'
  includes << 'opentcs-*/**'
  includes << 'src/**'
  includes << '.nb-gradle-properties'
  includes << '*.gradle'
  includes << 'gradlew'
  includes << 'gradlew.bat'
  includes << 'README.md'

  excludes << '.gradle'
  excludes << '**/build'
}

artifacts {
  archives distZip
  archives distTar
  archives distSrcZip
}

build {
  subprojects.each { dependsOn("${it.name}:build") }
  dependsOn installDist
}

// tag::cloneTask
task cloneProject(type: JavaExec) {
  main = 'org.opentcs.scripts.CloneScript'

  classpath = sourceSets.main.runtimeClasspath

  def integrationName = 'mycustomproject'
  def packageName = 'com.example'
  if (project.hasProperty('integrationName')) {
    integrationName = project.getProperty('integrationName')
  }
  if (project.hasProperty('packageName')) {
    packageName = project.getProperty('packageName')
  }

  // Pass command-line argument to script, if any.
  args integrationName, packageName
}
// tag::cloneTask

subprojects.each { publish.dependsOn("${it.name}:publish") }

publishing {
  publications {
    maven(MavenPublication) {
      artifact distZip
      artifact distSrcZip

      pom {
        artifactId = 'distribution'
      }
    }
  }
}