HttpClient/CMakeLists.txt at main · lzqlzzq/HttpClient · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
cmake_minimum_required(VERSION 3.14)
project(HttpClient VERSION 1.0.0 LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

# Options
option(HTTPCLIENT_BUILD_EXAMPLES "Build HttpClient example programs" OFF)

# Find libcurl
find_package(CURL 8.10.0 QUIET)
find_package(OpenSSL REQUIRED)

add_library(mycurl INTERFACE)

if (CURL_FOUND)
    message(STATUS "Using system libcurl: ${CURL_VERSION_STRING}")
    target_link_libraries(mycurl INTERFACE CURL::libcurl)
else()
    message(STATUS "System libcurl not found or too old; building vendored curl")

    include(FetchContent)

    # Build configuration
    set(BUILD_CURL_EXE OFF CACHE BOOL "" FORCE)
    set(BUILD_SHARED_LIBS OFF CACHE BOOL "" FORCE)
    set(BUILD_TESTING OFF CACHE BOOL "" FORCE)
    set(BUILD_LIBCURL_DOCS OFF CACHE BOOL "" FORCE)
    set(BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
    set(USE_LIBIDN2 OFF CACHE BOOL "" FORCE)
    set(CURL_USE_LIBPSL OFF CACHE BOOL "" FORCE)

    # Protocol configuration - HTTP(S) only
    set(HTTP_ONLY ON CACHE BOOL "" FORCE)

    # Fetch curl from GitHub
    FetchContent_Declare(
        curl
        GIT_REPOSITORY https://github.com/curl/curl.git
        GIT_TAG        curl-8_11_1
        GIT_SHALLOW    TRUE
    )
    FetchContent_MakeAvailable(curl)

    target_link_libraries(mycurl INTERFACE libcurl_static)
    target_compile_definitions(mycurl INTERFACE CURL_STATICLIB)
endif()

# Alias for curl
add_library(MyCurl::curl ALIAS mycurl)

# HttpClient library
add_library(HttpClient
    src/HttpClient.cpp
    src/HashHelper.cpp
)
target_include_directories(HttpClient
    PUBLIC
        ${CMAKE_CURRENT_SOURCE_DIR}/include
)
target_link_libraries(HttpClient PRIVATE MyCurl::curl OpenSSL::Crypto)
target_link_libraries(HttpClient INTERFACE MyCurl::curl OpenSSL::Crypto)

if(HTTPCLIENT_BUILD_EXAMPLES)
    add_executable(example examples/example.cpp)
    target_link_libraries(example PRIVATE HttpClient)
endif()