(feat) Add /sitemap.xml for crawlers (#29)

* (feat) Add /sitemap.xml - generated on demand

* Bump version 1.2.3

Author: kyle-neal

lib/revstack_web/controllers/sitemap_controller.ex

@@ -0,0 +1,42 @@
+defmodule RevstackWeb.SitemapController do
+  use RevstackWeb, :controller
+
+  @paths [
+    "/",
+    "/about",
+    "/services",
+    "/estimate",
+    "/contact",
+    "/privacy",
+    "/thanks",
+    "/whoami",
+    "/resume/kyle-neal-resume.pdf",
+    "/resume/download/kyle-neal-resume.pdf"
+  ]
+
+  def index(conn, _params) do
+    body =
+      [
+        ~s(<?xml version="1.0" encoding="UTF-8"?>),
+        ~s(<urlset xmlns="http://www.sitemaps.org/schemas/sitemap/0.9">),
+        Enum.map_join(@paths, "", &url_entry/1),
+        "</urlset>"
+      ]
+      |> IO.iodata_to_binary()
+
+    conn
+    |> put_resp_header("content-type", "application/xml; charset=utf-8")
+    |> send_resp(:ok, body)
+  end
+
+  defp url_entry(path) do
+    "<url><loc>#{absolute_url(path)}</loc></url>"
+  end
+
+  defp absolute_url(path) do
+    RevstackWeb.Endpoint.url()
+    |> URI.new!()
+    |> URI.merge(path)
+    |> to_string()
+  end
+end

lib/revstack_web/router.ex

@@ -26,6 +26,7 @@ defmodule RevstackWeb.Router do
   scope "/", RevstackWeb do
     pipe_through :browser
 
+    get "/sitemap.xml", SitemapController, :index
     get "/resume/kyle-neal-resume.pdf", ResumeController, :view
     get "/resume/download/kyle-neal-resume.pdf", ResumeController, :download
 

mix.exs

@@ -4,7 +4,7 @@ defmodule Revstack.MixProject do
   def project do
     [
       app: :revstack,
-      version: "1.2.2",
+      version: "1.2.3",
       elixir: "~> 1.15",
       elixirc_paths: elixirc_paths(Mix.env()),
       start_permanent: Mix.env() == :prod,

test/revstack_web/sitemap_controller_test.exs

@@ -0,0 +1,36 @@
+defmodule RevstackWeb.SitemapControllerTest do
+  use RevstackWeb.ConnCase, async: true
+
+  describe "GET /sitemap.xml" do
+    test "returns an XML sitemap for public routes", %{conn: conn} do
+      conn = get(conn, "/sitemap.xml")
+      base_url = RevstackWeb.Endpoint.url()
+
+      assert conn.status == 200
+      assert ["application/xml; charset=utf-8"] == get_resp_header(conn, "content-type")
+      assert conn.resp_body =~ ~s(<?xml version="1.0" encoding="UTF-8"?>)
+      assert conn.resp_body =~ ~s(<urlset xmlns="http://www.sitemaps.org/schemas/sitemap/0.9">)
+
+      for path <- [
+            "/",
+            "/about",
+            "/services",
+            "/estimate",
+            "/contact",
+            "/privacy",
+            "/thanks",
+            "/whoami",
+            "/resume/kyle-neal-resume.pdf",
+            "/resume/download/kyle-neal-resume.pdf"
+          ] do
+        assert conn.resp_body =~ "<loc>#{base_url}#{path}</loc>"
+      end
+    end
+
+    test "does not render a 404 response", %{conn: conn} do
+      conn = get(conn, "/sitemap.xml")
+
+      refute conn.resp_body == "Not Found"
+    end
+  end
+end