kmaker-validator/build.gradle at develop · kmaker-io/kmaker-validator · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
plugins {
    id 'java-library'
    id 'checkstyle'
    id "com.vanniktech.maven.publish" version "0.36.0"
}

repositories {
    mavenCentral()
}

description = 'io.kmaker:kmaker-validator'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.release = 17
}

checkstyle {
    toolVersion = "13.1.0"
}

tasks.withType(Checkstyle).configureEach {
    reports {
        xml.required = false
        html.required = true
        sarif.required = true
    }
}

tasks.withType(Javadoc).configureEach {
    options {
        // This stops the "warning: no comment" and HTML syntax messages.
        addStringOption('Xdoclint:none', '-quiet')
    }
}

ext {
    commonsBeanutilsVersion = "1.11.0"
    jakartaElApiVersion = "6.0.1"
    commonsTextVersion = "1.15.0"
    doxiaSiteRendererVersion = "2.0.0"
    expresslyVersion = "6.0.0-M1"
    hibernateValidatorVersion = "8.0.2.Final"
    hibernateValidatorProcessorVersion = "8.0.2.Final"
    junitBomVersion = "5.10.0"
}

dependencies {
    api "jakarta.el:jakarta.el-api:${jakartaElApiVersion}"
    api "org.glassfish.expressly:expressly:${expresslyVersion}"
    implementation "org.hibernate.validator:hibernate-validator:${hibernateValidatorVersion}"
    implementation "commons-beanutils:commons-beanutils:${commonsBeanutilsVersion}"
    implementation "org.apache.commons:commons-text:${commonsTextVersion}"

    annotationProcessor "org.hibernate.validator:hibernate-validator-annotation-processor:${hibernateValidatorProcessorVersion}"

    testImplementation platform("org.junit:junit-bom:${junitBomVersion}")
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    useJUnitPlatform()
}

// Docs: https://vanniktech.github.io/gradle-maven-publish-plugin/central/
mavenPublishing {
    // 1. Tell the plugin what to publish
    configureBasedOnAppliedPlugins()

    // 2. Deployment Targets (Replaces your repositories block)
    // For the new Central Portal (central.sonatype.com)
    publishToMavenCentral(true)

    // 3. Signing (Replaces your signing block)
    signAllPublications()

    // 4. POM Metadata (The plugin needs this to generate the POM)
    pom {
        name = 'Kmaker Validator'
        description = 'A validation library built on top of Hibernate Validator, providing custom constraints for common use cases. Designed to reduce redundant validation logic by addressing gaps in Hibernate Validator\'s built-in constraints, based on real-world experience.'
        url = 'https://github.com/kmaker-io/kmaker-validator'
        licenses {
            license {
                name = 'Apache 2.0'
                url = 'https://www.apache.org/licenses/LICENSE-2.0.html'
            }
        }
        developers {
            developer {
                id = 'yongan.touch@kmaker.io'
                name = 'TOUCH Yong An'
                email = 'yongan.touch@kmaker.io'
            }
        }
        scm {
            connection = 'scm:git:git://github.com/kmaker-io/kmaker-validator.git'
            developerConnection = 'scm:git:ssh://github.com:kmaker-io/kmaker-validator.git'
            url = 'https://github.com/kmaker-io/kmaker-validator'
        }
    }
}