opal/build.gradle.kts at master · devceanias/opal · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
group = "net.oceanias"
version = "5.2.2"

plugins {
    id("java-library")
    id("maven-publish")

    alias(libs.plugins.shadow)
    alias(libs.plugins.zapper)
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(21))
    }

    withSourcesJar()
    withJavadocJar()
}

repositories {
    mavenLocal()
    mavenCentral()

    maven("https://central.sonatype.com/repository/maven-snapshots/")
    maven("https://repo.codemc.io/repository/maven-public/")
    maven("https://repo.papermc.io/repository/maven-public/")
    maven("https://oss.sonatype.org/content/groups/public/")
    maven("https://repo.xenondevs.xyz/releases")
    maven("https://jitpack.io")
}

publishing {
    publications {
        create<MavenPublication>("jitpack") {
            from(components["java"])
        }
    }
}

dependencies {
    annotationProcessor(libs.lombok)

    api(libs.zapper)

    compileOnly(libs.lombok)
    compileOnly(libs.paper)
    compileOnly(variantOf(libs.inventoryaccess) { classifier("remapped-mojang") })

    compileOnlyApi(libs.invui)
    compileOnlyApi(libs.commandapi)
    compileOnlyApi(libs.configlib)
    compileOnlyApi(libs.commons.text)
    compileOnlyApi(libs.minitext)

    zap(libs.commandapi)
    zap(libs.configlib)
    zap(libs.commons.text)
    zap(libs.minitext)
}

zapper {
    relocationPrefix = "$group.${name.lowercase()}.libraries"
}

defaultTasks("build")

tasks {
    processResources {
        duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    }

    withType<Jar>().configureEach {
        archiveBaseName.set(rootProject.name.replaceFirstChar { char -> char.uppercase() })
    }

    build {
        dependsOn(jar)
    }
}