mitm-cache/fetch.nix at master · chayleaf/mitm-cache · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
{ lib
, fetchurl
, runCommand
, writeText
}:

{ name ? "deps"
, data
, dontFixup ? true
, ...
}
@ attrs:

let
  data' =
    builtins.removeAttrs
    (if builtins.isPath data then builtins.fromJSON (builtins.readFile data) else data)
    [ "!version" ];
  urlToPath = url:
    if lib.hasPrefix "https://" url then (
      let
        url' = lib.drop 2 (lib.splitString "/" url);
      in "https/${builtins.concatStringsSep "/" url'}"
    )
    else builtins.replaceStrings ["://"] ["/"] url;
  code = ''
    mkdir -p "$out"
    cd "$out"
  '' + builtins.concatStringsSep "" (lib.mapAttrsToList (url: info:
  let
    key = builtins.head (builtins.attrNames info);
    val = info.${key};
    path = urlToPath url;
    name = baseNameOf path;
    source = {
      redirect = "$out/${urlToPath val}";
      hash = fetchurl { inherit url; hash = val; };
      text = writeText name val;
    }.${key} or (throw "Unknown key: ${url}");
  in ''
    mkdir -p "${dirOf path}"
    ln -s "${source}" "${path}"
  '') data');
in
  runCommand name (builtins.removeAttrs attrs [ "name" "data" ]) code