cfAWSWrapper/amazonSTS.cfc at master · cfchris/cfAWSWrapper · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
<cfcomponent output="false" extends="amazonAWS" >
	<cffunction name="init" access="public" returntype="amazonSTS" >
		<cfargument name="awsAccessKeyId" type="string" required="true"/>
		<cfargument name="secretAccessKey" type="string" required="true"/>
		<cfargument name="endPoint" type="string" required="true" default="sts.amazonaws.com"/>

		<cfset variables.awsAccessKeyId = arguments.awsAccessKeyId />
		<cfset variables.secretAccesskey = arguments.secretAccessKey />
		<cfset variables.endPoint = arguments.endPoint />
		<cfset variables.requestMethod = 'no-header' />
		<cfset variables.version = '2011-06-15' />
		<cfset variables.protocol = 'https://' />
		<cfreturn this />
	</cffunction>

	<cffunction name="GetFederationToken" access="public" returntype="Struct" >
    		<cfargument name="Name" type="string" required="true" >
    		<cfargument name="DurationSeconds" type="string" required="false" default="" >
    		<cfargument name="Policy" type="string" required="false" default="" >

    		<cfset var stResponse = createResponse() />
    		<cfset var body = "Action=GetFederationToken&Name=" & trim(arguments.name)/>

    		<cfif len(trim(arguments.DurationSeconds))>
    			<cfset body &= "&DurationSeconds=" & trim(arguments.DurationSeconds) />
    		</cfif>

    		<cfif len(trim(arguments.Policy))>
    			<cfset body &= "&Policy=" & trim(arguments.Policy) />
    		</cfif>

    		<cfset var rawResult = makeRequestFull(
    							endPoint = variables.endPoint,
    							awsAccessKeyId = variables.awsAccessKeyId,
    							secretAccesskey = variables.secretAccesskey,
    							body=body,
    							requestMethod = variables.requestMethod,
    							version = variables.version,
    							protocol = variables.protocol ) />

    		<cfif rawResult.statusCode neq 200>
    			<cfset error = getResultNodes(xmlParse(rawResult.fileContent),'Error')[1] />
    			<cfset stResponse.success=false />
    			<cfset stResponse.statusCode=rawResult.statusCode />
    			<cfset stResponse.error=error.Code.xmlText/>
    			<cfset stResponse.errorType=error.Type.xmlText/>
    			<cfset stResponse.errorMessage=error.Message.xmlText/>
    		<cfelse>
			<cfset dataResult = getResultNodes(xmlParse(rawResult.filecontent),'GetFederationTokenResult')[1] />

    			<cfset stResponse.result = {
							Credentials=createCredentialsObject(dataResult.Credentials),
							FederatedUser=createFederatedUserObject(dataResult.FederatedUser),
							PackedPolicySize=getValue(dataResult,'PackedPolicySize')
						} />

    		</cfif>

    		<cfset stResponse.requestID = getResultNodes(xmlParse(rawResult.fileContent),'RequestId')[1].xmltext />

    		<cfreturn stResponse />
    	</cffunction>

	<cffunction name="GetSessionToken" access="public" returntype="Struct" >
    		<cfargument name="TokenCode" type="string" required="false" default="">
		<cfargument name="SerialNumber" type="string" required="false" default="">
		<cfargument name="DurationSeconds" type="string" required="false" default="">

    		<cfset var stResponse = createResponse() />
    		<cfset var body = "Action=GetSessionToken"/>

    		<cfif len(trim(arguments.TokenCode))>
    			<cfset body &= "&TokenCode=" & trim(arguments.TokenCode) />
    		</cfif>

    		<cfif len(trim(arguments.SerialNumber))>
    			<cfset body &= "&SerialNumber=" & trim(arguments.SerialNumber) />
    		</cfif>

    		<cfif len(trim(arguments.DurationSeconds))>
    			<cfset body &= "&DurationSeconds=" & trim(arguments.DurationSeconds) />
    		</cfif>

    		<cfset var rawResult = makeRequestFull(
    							endPoint = variables.endPoint,
    							awsAccessKeyId = variables.awsAccessKeyId,
    							secretAccesskey = variables.secretAccesskey,
    							body=body,
    							requestMethod = variables.requestMethod,
    							version = variables.version,
    							protocol = variables.protocol ) />

    		<cfif rawResult.statusCode neq 200>
    			<cfset error = getResultNodes(xmlParse(rawResult.fileContent),'Error')[1] />
    			<cfset stResponse.success=false />
    			<cfset stResponse.statusCode=rawResult.statusCode />
    			<cfset stResponse.error=error.Code.xmlText/>
    			<cfset stResponse.errorType=error.Type.xmlText/>
    			<cfset stResponse.errorMessage=error.Message.xmlText/>
    		<cfelse>
    			<cfset dataResult = getResultNodes(xmlParse(rawResult.filecontent),'Credentials')[1] />

    			<cfset stResponse.result = {
							credentials=createCredentialsObject(dataResult)
						} />
    		</cfif>

    		<cfset stResponse.requestID = getResultNodes(xmlParse(rawResult.fileContent),'RequestId')[1].xmltext />

    		<cfreturn stResponse />
    	</cffunction>

    	<cffunction name="createCredentialsObject" access="public" returntype="Struct" output="false" >
		<cfargument name="stXML" type="xml" required="false" default="#xmlNew()#">

		<cfset var response = {
					AccessKeyId=getValue(arguments.stXML,'AccessKeyId'),
					Expiration=getValue(arguments.stXML,'Expiration'),
					SecretAccessKey=getValue(arguments.stXML,'SecretAccessKey'),
					SessionToken=getValue(arguments.stXML,'SessionToken')
				} />

		<cfreturn response />
	</cffunction>

	<cffunction name="createFederatedUserObject" access="public" returntype="Struct" output="false" >
		<cfargument name="stXML" type="xml" required="false" default="#xmlNew()#">

		<cfset var response = {
					Arn=getValue(arguments.stXML,'Arn'),
					FederatedUserId=getValue(arguments.stXML,'FederatedUserId')
				} />

		<cfreturn response />
	</cffunction>
</cfcomponent>