ryzencap/flake.nix at main · cch000/ryzencap · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
{
  description = "Service to limit power consumption on ryzen cpus";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    treefmt-nix.url = "github:numtide/treefmt-nix";
  };
  outputs = {
    nixpkgs,
    treefmt-nix,
    self,
    ...
  }: let
    pkgs = nixpkgs.legacyPackages.x86_64-linux;

    treefmtEval = treefmt-nix.lib.evalModule pkgs {
      projectRootFile = "flake.nix";
      programs = {
        alejandra.enable = true;
        deadnix.enable = true;
        statix.enable = true;
        rustfmt.enable = true;
      };
    };

    treefmt = treefmtEval.config.build;

    buildInputs = [pkgs.pciutils];

    nativeBuildInputs = with pkgs; [
      clang
      pkg-config
      cmake
      rustPlatform.bindgenHook
    ];

    ryzencap = let
      name = "ryzencap";
    in
      pkgs.rustPlatform.buildRustPackage {
        inherit buildInputs nativeBuildInputs name;
        cargoLock.lockFile = ./Cargo.lock;
        src = ./.;
        meta.mainProgram = name;
      };
  in {
    nixosModules.ryzencap = import ./modules self;

    formatter.${pkgs.system} = treefmt.wrapper;

    checks.${pkgs.system}.formatting = treefmt.check self;

    devShells.${pkgs.system}.default = pkgs.mkShell {
      inherit buildInputs nativeBuildInputs;
      inputsFrom = [treefmt.devShell];
      packages = with pkgs; [
        nil
        rustc
        cargo
        clippy
        rust-analyzer
      ];
    };

    packages.${pkgs.system} = {
      inherit ryzencap;
      default = ryzencap;
    };
  };
}