commons-java/build.gradle at main · autonomouslogic/commons-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
plugins {
	id "java"
	id "idea"
	id "application"
	id "jacoco"
	id "io.freefair.lombok" version "9.5.0"
	id "org.danilopianini.git-sensitive-semantic-versioning-gradle-plugin" version "7.0.22"
	id "com.diffplug.spotless" version "8.7.0"
	id "signing"
	id "org.danilopianini.publish-on-central" version "9.2.2"
}

group "com.autonomouslogic.commons"


java {
	withJavadocJar()
	withSourcesJar()
	sourceCompatibility = JavaVersion.VERSION_21
	targetCompatibility = JavaVersion.VERSION_21
}

repositories {
	mavenCentral()
}

dependencies {
	implementation "com.google.guava:guava:33.6.0-jre"
	//implementation "com.diffplug.durian:durian:3.4.0"

	compileOnly "io.reactivex.rxjava3:rxjava:3.1.12"

	testImplementation "org.mockito:mockito-core:5.23.0"
	testImplementation "org.junit.jupiter:junit-jupiter-api:5.14.4"
	testImplementation "org.junit.jupiter:junit-jupiter-params:5.14.4"
	testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:5.14.4"
	testImplementation "commons-io:commons-io:2.22.0"
	testImplementation "io.reactivex.rxjava3:rxjava:3.1.12"
	testImplementation "org.junit-pioneer:junit-pioneer:2.3.0"
}

test {
	useJUnitPlatform()

	jvmArgs = [
		"--add-opens", "java.base/java.lang=ALL-UNNAMED",
		"--add-opens", "java.base/java.util=ALL-UNNAMED"
	]

	testLogging {
		events = [ "FAILED", "PASSED", "SKIPPED" ]
		showExceptions = true
		exceptionFormat = "FULL"
		showExceptions = true
		showCauses = true
		showStackTraces = true
	}
}

jacocoTestReport {
	executionData(test)
	reports {
		xml.required = true
		html.required = true
	}
}

spotless {
	java {
		palantirJavaFormat()
		leadingSpacesToTabs()
	}

	groovyGradle {
		leadingSpacesToTabs()
	}
}

javadoc {
	options {
		addBooleanOption "Xdoclint:all,-html,-missing", true
	}
}

publishOnCentral {
	repoOwner = "autonomouslogic"
	projectDescription = "Commons Java functions."
	projectLongName = "Commons Java"
	projectUrl = "https://github.com/autonomouslogic/commons-java"
	licenseName = "MIT-0"
	licenseUrl = "https://spdx.org/licenses/MIT-0.html"
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			from(components.java)
		}
	}
}

publishing.publications.withType(MavenPublication).configureEach {
	pom {
		developers {
			developer {
				id = "kennethjor"
				name = "Kenneth Jorgensen"
				email = "kenneth@autonomouslogic.com"
				url = "https://kennethjorgensen.com/"
			}
		}
	}
}

signing {
	sign publishing.publications.mavenJava
}