opencattus/ProjectOptions.cmake at master · VersatusHPC/opencattus · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
include(cmake/SystemLink.cmake)
include(cmake/LibFuzzer.cmake)
include(CMakeDependentOption)
include(CheckCXXCompilerFlag)

macro(opencattus_supports_sanitizers)
  if((CMAKE_CXX_COMPILER_ID MATCHES ".*Clang.*" OR CMAKE_CXX_COMPILER_ID MATCHES ".*GNU.*") AND NOT WIN32)
    set(SUPPORTS_UBSAN ON)
  else()
    set(SUPPORTS_UBSAN OFF)
  endif()

  if((CMAKE_CXX_COMPILER_ID MATCHES ".*Clang.*" OR CMAKE_CXX_COMPILER_ID MATCHES ".*GNU.*") AND WIN32)
    set(SUPPORTS_ASAN OFF)
  else()
    set(SUPPORTS_ASAN ON)
  endif()
endmacro()

macro(opencattus_setup_options)
  option(opencattus_ENABLE_HARDENING "Enable hardening" ON)
  option(opencattus_ENABLE_COVERAGE "Enable coverage reporting" OFF)
  cmake_dependent_option(
    opencattus_ENABLE_GLOBAL_HARDENING
    "Attempt to push hardening options to built dependencies"
    ON
    opencattus_ENABLE_HARDENING
    OFF)

  if(NOT PROJECT_IS_TOP_LEVEL OR opencattus_PACKAGING_MAINTAINER_MODE)
    option(opencattus_ENABLE_IPO "Enable IPO/LTO" OFF)
    option(opencattus_WARNINGS_AS_ERRORS "Treat Warnings As Errors" OFF)
    option(opencattus_ENABLE_USER_LINKER "Enable user-selected linker" OFF)
    option(opencattus_ENABLE_SANITIZER_ADDRESS "Enable address sanitizer" OFF)
    option(opencattus_ENABLE_SANITIZER_LEAK "Enable leak sanitizer" OFF)
    option(opencattus_ENABLE_SANITIZER_UNDEFINED "Enable undefined sanitizer" OFF)
    option(opencattus_ENABLE_SANITIZER_THREAD "Enable thread sanitizer" OFF)
    option(opencattus_ENABLE_SANITIZER_MEMORY "Enable memory sanitizer" OFF)
    option(opencattus_ENABLE_UNITY_BUILD "Enable unity builds" OFF)
    option(opencattus_ENABLE_CLANG_TIDY "Enable clang-tidy" OFF)
    option(opencattus_ENABLE_CPPCHECK "Enable cpp-check analysis" OFF)
    option(opencattus_ENABLE_PCH "Enable precompiled headers" OFF)
    option(opencattus_ENABLE_CACHE "Enable ccache" OFF)
  else()
    option(opencattus_ENABLE_IPO "Enable IPO/LTO" ON)
    option(opencattus_WARNINGS_AS_ERRORS "Treat Warnings As Errors" OFF)
    option(opencattus_ENABLE_USER_LINKER "Enable user-selected linker" OFF)
    option(opencattus_ENABLE_SANITIZER_ADDRESS "Enable address sanitizer" OFF)
    option(opencattus_ENABLE_SANITIZER_LEAK "Enable leak sanitizer" OFF)
    option(opencattus_ENABLE_SANITIZER_UNDEFINED "Enable undefined sanitizer" OFF)
    option(opencattus_ENABLE_SANITIZER_THREAD "Enable thread sanitizer" OFF)
    option(opencattus_ENABLE_SANITIZER_MEMORY "Enable memory sanitizer" OFF)
    option(opencattus_ENABLE_UNITY_BUILD "Enable unity builds" OFF)
    option(opencattus_ENABLE_CLANG_TIDY "Enable clang-tidy" OFF)
    option(opencattus_ENABLE_CPPCHECK "Enable cpp-check analysis" ON)
    option(opencattus_ENABLE_PCH "Enable precompiled headers" OFF)
    option(opencattus_ENABLE_CACHE "Enable ccache" ON)
  endif()

  if(NOT PROJECT_IS_TOP_LEVEL)
    mark_as_advanced(
      opencattus_ENABLE_IPO
      opencattus_WARNINGS_AS_ERRORS
      opencattus_ENABLE_USER_LINKER
      opencattus_ENABLE_SANITIZER_ADDRESS
      opencattus_ENABLE_SANITIZER_LEAK
      opencattus_ENABLE_SANITIZER_UNDEFINED
      opencattus_ENABLE_SANITIZER_THREAD
      opencattus_ENABLE_SANITIZER_MEMORY
      opencattus_ENABLE_UNITY_BUILD
      opencattus_ENABLE_CLANG_TIDY
      opencattus_ENABLE_CPPCHECK
      opencattus_ENABLE_COVERAGE
      opencattus_ENABLE_PCH
      opencattus_ENABLE_CACHE)
  endif()

  opencattus_check_libfuzzer_support(LIBFUZZER_SUPPORTED)
  if(LIBFUZZER_SUPPORTED AND (opencattus_ENABLE_SANITIZER_ADDRESS OR opencattus_ENABLE_SANITIZER_THREAD OR opencattus_ENABLE_SANITIZER_UNDEFINED))
    set(DEFAULT_FUZZER ON)
  else()
    set(DEFAULT_FUZZER OFF)
  endif()

  option(opencattus_BUILD_FUZZ_TESTS "Enable fuzz testing executable" ${DEFAULT_FUZZER})

endmacro()

macro(opencattus_global_options)
  if(opencattus_ENABLE_IPO)
    include(cmake/InterproceduralOptimization.cmake)
    opencattus_enable_ipo()
  endif()

  if(opencattus_ENABLE_HARDENING AND opencattus_ENABLE_GLOBAL_HARDENING)
    include(cmake/Hardening.cmake)
    if(NOT SUPPORTS_UBSAN
       OR opencattus_ENABLE_SANITIZER_UNDEFINED
       OR opencattus_ENABLE_SANITIZER_ADDRESS
       OR opencattus_ENABLE_SANITIZER_THREAD
       OR opencattus_ENABLE_SANITIZER_LEAK)
      set(ENABLE_UBSAN_MINIMAL_RUNTIME FALSE)
    else()
      set(ENABLE_UBSAN_MINIMAL_RUNTIME TRUE)
    endif()
    message("${opencattus_ENABLE_HARDENING} ${ENABLE_UBSAN_MINIMAL_RUNTIME} ${opencattus_ENABLE_SANITIZER_UNDEFINED}")
    opencattus_enable_hardening(opencattus_options ON ${ENABLE_UBSAN_MINIMAL_RUNTIME})
  endif()
endmacro()

macro(opencattus_local_options)
  if(PROJECT_IS_TOP_LEVEL)
    include(cmake/StandardProjectSettings.cmake)
  endif()

  add_library(opencattus_warnings INTERFACE)
  add_library(opencattus_options INTERFACE)

  include(cmake/CompilerWarnings.cmake)
  opencattus_set_project_warnings(
    opencattus_warnings
    ${opencattus_WARNINGS_AS_ERRORS}
    ""
    ""
    ""
    "")

  if(opencattus_ENABLE_USER_LINKER)
    include(cmake/Linker.cmake)
    configure_linker(opencattus_options)
  endif()

  include(cmake/Sanitizers.cmake)
  opencattus_enable_sanitizers(
    opencattus_options
    ${opencattus_ENABLE_SANITIZER_ADDRESS}
    ${opencattus_ENABLE_SANITIZER_LEAK}
    ${opencattus_ENABLE_SANITIZER_UNDEFINED}
    ${opencattus_ENABLE_SANITIZER_THREAD}
    ${opencattus_ENABLE_SANITIZER_MEMORY})

  set_target_properties(opencattus_options PROPERTIES UNITY_BUILD ${opencattus_ENABLE_UNITY_BUILD})

  if(opencattus_ENABLE_PCH)
    target_precompile_headers(
      opencattus_options
      INTERFACE
      <vector>
      <string>
      <utility>)
  endif()

  if(opencattus_ENABLE_CACHE)
    include(cmake/Cache.cmake)
    opencattus_enable_cache()
  endif()

  include(cmake/StaticAnalyzers.cmake)
  if(opencattus_ENABLE_CLANG_TIDY)
    opencattus_enable_clang_tidy(opencattus_options ${opencattus_WARNINGS_AS_ERRORS})
  endif()

  if(opencattus_ENABLE_CPPCHECK)
    opencattus_enable_cppcheck(${opencattus_WARNINGS_AS_ERRORS} "" # override cppcheck options
    )
  endif()

  if(opencattus_ENABLE_COVERAGE)
    include(cmake/Tests.cmake)
    opencattus_enable_coverage(opencattus_options)
  endif()

  if(opencattus_WARNINGS_AS_ERRORS)
    check_cxx_compiler_flag("-Wl,--fatal-warnings" LINKER_FATAL_WARNINGS)
    if(LINKER_FATAL_WARNINGS)
      # This is not working consistently, so disabling for now
      # target_link_options(opencattus_options INTERFACE -Wl,--fatal-warnings)
    endif()
  endif()

  if(opencattus_ENABLE_HARDENING AND NOT opencattus_ENABLE_GLOBAL_HARDENING)
    include(cmake/Hardening.cmake)
    if(NOT SUPPORTS_UBSAN
       OR opencattus_ENABLE_SANITIZER_UNDEFINED
       OR opencattus_ENABLE_SANITIZER_ADDRESS
       OR opencattus_ENABLE_SANITIZER_THREAD
       OR opencattus_ENABLE_SANITIZER_LEAK)
      set(ENABLE_UBSAN_MINIMAL_RUNTIME FALSE)
    else()
      set(ENABLE_UBSAN_MINIMAL_RUNTIME TRUE)
    endif()
    opencattus_enable_hardening(opencattus_options OFF ${ENABLE_UBSAN_MINIMAL_RUNTIME})
  endif()

endmacro()