feonix-docs/flake.nix at main · PurdueAerialRoboticsTeam/feonix-docs · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
{
  description = "Feonix Documentation";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";
    utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, pre-commit-hooks, utils }:
    utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; };
        python3Packages = (pkgs.python3.override {
          packageOverrides = pFinal: pPrev: {
            mkdocs-with-pdf = pFinal.callPackage ./mkdocs-with-pdf.nix { };
            plantuml-markdown = pPrev.plantuml-markdown.override {
              plantuml = pkgs.plantuml-c4;
            };
          };
        }).pkgs;
      in
      rec {
        packages = {
          html = python3Packages.callPackage ./build.nix { };
          pdf = packages.html.overrideAttrs (old: {
            name = "feonix-documentation.pdf";
            ENABLE_PDF_EXPORT = "true";
            buildPhase = ''
              mkdocs build
              cp site/pdf/document.pdf $out
            '';
          });
          default = packages.html;
        };

        apps = {
          serve-docs = {
            type = "app";
            program = builtins.toString (pkgs.writeShellScript "serve-docs" ''
              exec ${pkgs.python3}/bin/python3 -m http.server \
              --bind 127.0.0.1 \
              --directory ${packages.html}
            '');
          };
          serve-dev = {
            type = "app";
            program = builtins.toString (pkgs.writeShellScript "serve-dev" ''
              echo To start a live reload server, run  $ mkdocs serve
            '');
          };
          default = apps.serve-docs;
        };

        checks = {
          pre-commit-check = pre-commit-hooks.lib.${system}.run {
            src = ./.;
            hooks = {
              cspell = {
                enable = true;
                entry = "${pkgs.nodePackages.cspell}/bin/cspell --words-only";
                types = [ "markdown" ];
              };
              markdownlint.enable = true;
              nixpkgs-fmt.enable = true;
              statix.enable = true;
            };
          };
        };

        devShell = with pkgs; mkShell {
          inputsFrom = [ packages.html ];
          shellHook = ''
            ${checks.pre-commit-check.shellHook}
          '';
        };
      }
    );
}