AlcarisCore/build.gradle at develop · AlcarisMinecraftServer/AlcarisCore · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
plugins {
    id 'java'
    id 'maven-publish'
    id 'com.gradleup.shadow' version '8.3.6'
}

group = 'net.alcaris'
version = System.getenv("BUILD_VERSION") ?: '1.0.0-SNAPSHOT'

repositories {
    mavenCentral()
    maven {
        name = 'papermc'
        url = 'https://repo.papermc.io/repository/maven-public/'
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
}

dependencies {
    compileOnly 'io.papermc.paper:paper-api:1.21.8-R0.1-SNAPSHOT'
    implementation 'com.google.code.gson:gson:2.10.1'
    implementation 'com.squareup.okhttp3:okhttp:4.9.3'
    implementation 'org.java-websocket:Java-WebSocket:1.5.3'

    implementation 'com.zaxxer:HikariCP:5.1.0'
    implementation 'com.mysql:mysql-connector-j:8.2.0'
    implementation 'org.slf4j:slf4j-api:2.0.9'
    implementation 'org.slf4j:slf4j-simple:2.0.9'
}

def targetJavaVersion = 21
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact shadowJar
            artifactId = 'AlcarisCore'
        }
    }
    repositories {
        maven {
            name = "alcaris-repository"
            url = "https://repo.onp.admin.alcaris.net/releases"

            credentials {
                username = findProperty("repoUser") ?: System.getenv("REPO_USER")
                password = findProperty("repoPassword") ?: System.getenv("REPO_PASS")
            }

            authentication {
                basic(BasicAuthentication)
            }
        }
    }
}

shadowJar {
    archiveClassifier.set('')
}

build.dependsOn shadowJar